home *** CD-ROM | disk | FTP | other *** search
/ Workbench Add-On / Workbench Add-On - Volume 1.iso / BBS-Archive / Dev / GNU-SMALLTALK.lha / Point.st < prev    next >
Text File  |  1992-02-15  |  4KB  |  229 lines
  1. "=====================================================================
  2. |
  3. |    Point Class Definitions
  4. |
  5.  ====================================================================="
  6.  
  7. "======================================================================
  8. |
  9. | Copyright (C) 1990, 1991, 1992 Free Software Foundation, Inc.
  10. | By Doug McCallum <uunet!ico.isc.com!dougm>
  11. | Additions by sbb@eng.sun.com (Steve Byrne)
  12. |
  13. | This file is part of GNU Smalltalk.
  14. |
  15. | GNU Smalltalk is free software; you can redistribute it and/or modify it
  16. | under the terms of the GNU General Public License as published by the Free
  17. | Software Foundation; either version 1, or (at your option) any later version.
  18. | 
  19. | GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
  20. | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  21. | FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  22. | details.
  23. | 
  24. | You should have received a copy of the GNU General Public License along with
  25. | GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
  26. | Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  
  27. |
  28.  ======================================================================"
  29.  
  30.  
  31. "
  32. |     Change Log
  33. | ============================================================================
  34. | Author       Date       Change
  35. | sbb         10 Jul 91      Added = for Points (= from Object isn't right)
  36. |
  37. | dougm      16 Apr 90    Created basic Point class.
  38. |
  39. "
  40.  
  41. Object subclass: #Point
  42.        instanceVariableNames: 'x y'
  43.        classVariableNames: ''
  44.        poolDictionaries: ''
  45.        category: nil
  46. !
  47.  
  48. Point comment:
  49. 'Beginning of a Point class for simple display manipulation.  Has not been
  50.  exhaustively tested but appears to work for the basic primitives and for
  51.  the needs of the Rectangle class.' !
  52.  
  53. !Number methodsFor: 'point creation'!
  54.  
  55. @ y
  56.     ^ Point x: self y: y
  57. !
  58.  
  59. asPoint
  60.     ^Point x: self y: self
  61. !!
  62.  
  63.  
  64. !Point class methodsFor: 'instance creation'!
  65.  
  66. x: xInteger y: yInteger
  67.     ^self new x: xInteger y: yInteger
  68. !!
  69.  
  70. !Point methodsFor: 'printing'!
  71.  
  72. printOn: aStream
  73.     aStream print: x;
  74.     nextPut: $@;
  75.     print: y
  76. !!
  77.  
  78. !Point methodsFor: 'storing'!
  79.  
  80. storeOn: aStream
  81.     aStream store: x;
  82.     nextPut: $@;
  83.     store: y
  84. !!
  85.  
  86. !Point methodsFor: 'accessing'!
  87.  
  88. x
  89.     ^x
  90. !
  91.  
  92. y
  93.     ^y
  94. !
  95.  
  96. x: aNumber
  97.     x _ aNumber
  98. !
  99.  
  100. y: aNumber
  101.     y _ aNumber
  102. !
  103.  
  104. x: anXNumber y: aYNumber
  105.     x _ anXNumber.
  106.     y _ aYNumber
  107. !!
  108.  
  109. !Point methodsFor: 'converting'!
  110.  
  111. asPoint
  112.     ^self            "But I already AM a point!"
  113. !
  114.  
  115. hash
  116.     ^(x abs + y abs) truncated
  117. !!
  118.  
  119. !Point methodsFor: 'arithmetic'!
  120.  
  121. + delta
  122.     delta _ delta asPoint.
  123.     ^Point x: (x + delta x) y: (y + delta y)
  124. !
  125.  
  126. - delta
  127.     delta _ delta asPoint.
  128.     ^Point x: (x - delta x) y: (y - delta y)
  129. !
  130.  
  131. * scale
  132.     scale _ scale asPoint.
  133.     ^Point x: (x * scale x) y: (y * scale y)
  134. !
  135.  
  136. / scale
  137.     scale _ scale asPoint.
  138.     ^Point x: (x / scale x) y: (y / scale y)
  139. !
  140.  
  141. // scale
  142.     scale _ scale asPoint.
  143.     ^Point x: (x // scale x) y: (y // scale y)
  144. !
  145.  
  146. abs
  147.     ^Point x: (x abs) y: (y abs)
  148. !!
  149.  
  150. !Point methodsFor: 'truncation and round off'!
  151. rounded
  152.     ^Point x: (x rounded) y: (y rounded)
  153. !
  154.  
  155. truncateTo: grid
  156.     ^Point x: (x truncateTo: grid) y: (y truncateTo: grid)
  157.  
  158. !!
  159.  
  160.  
  161. !Point methodsFor: 'comparing'!
  162.  
  163. = aPoint
  164.     ^(x = aPoint x) and: [ y = aPoint y ]
  165. !
  166.  
  167. < aPoint
  168.     ^(x < aPoint x) and: [ (y < aPoint y) ]
  169. !
  170.  
  171. > aPoint
  172.     ^(x > aPoint x) and: [ (y > aPoint y) ]
  173. !
  174.  
  175. <= aPoint
  176.     ^(self > aPoint) not    "unverified"
  177. !
  178.  
  179. >= aPoint
  180.     ^(self < aPoint) not    "unverified"
  181. !
  182.  
  183. max: aPoint
  184.     (self >aPoint )
  185.        ifTrue: [ ^self ]
  186.        ifFalse:[ ^aPoint ]
  187. !
  188.  
  189. min: aPoint
  190.     (self < aPoint)
  191.        ifTrue: [^ self ]
  192.        ifFalse:[^ aPoint ]
  193. !!
  194.  
  195. !Point methodsFor: 'point functions'!
  196.  
  197. dist: aPoint
  198.     | a b |
  199.     a _ x - (aPoint x).
  200.     b _ y - (aPoint y).
  201.     ^((a squared) + (b squared)) sqrt
  202. !
  203.  
  204. dotProduct: aPoint
  205.     ^(x * aPoint x) + (y * aPoint y)
  206. !
  207.  
  208. grid: aPoint
  209.     ^Point x: (x roundTo: (aPoint x)) y: (y roundTo: (aPoint y))
  210. !
  211.  
  212. normal
  213. "rotate the Point 90degrees clockwise and get the unit vector"
  214.     |len|
  215.     len _ ((x squared) + (y squared)) sqrt.
  216.     ^Point x: ((y asFloat negated)/len) y: (x/len)
  217. !
  218.  
  219. transpose
  220.     ^Point x: y y: x
  221. !
  222.  
  223. truncatedGrid: aPoint
  224.     ^Point x: (x truncateTo: (aPoint x)) y: (y truncateTo: (aPoint y))
  225. !!
  226.  
  227.  
  228.  
  229.